MODEL:
TITLE MMP;
SETS:
	NODES: NODESS;
	LINKS1(NODES): F,H;
	LINKS2(NODES, NODES): W,R,C;
	LINKS2H(NODES, NODES): Z,G; 
	LINKS3(NODES, NODES, NODES): FAD;
	LINKS4(NODES, NODES, NODES, NODES): Y;	
ENDSETS
DATA:
	N = @FILE(instanca1.txt);
	NODES = N1 .. N25;
	W = @FILE(instanca1.txt);
	R = @FILE(instanca1.txt);
	C = @FILE(instanca1.txt);
	F = @FILE(instanca1.txt);
	G = @FILE(instanca1.txt);
	ALFA = @FILE(instanca1.txt);
ENDDATA
!FUNKCIJA CILJA;	
	MAX = @SUM(LINKS4(I,J,K,L): R(I,J)* W(I,J)*Y(I,J,K,L)) -
		@SUM(LINKS4(I,J,K,L): (C(I,K)+C(L,J))*W(I,J)*Y(I,J,K,L)) -
 		@SUM(LINKS3(I,K,L): ALFA*C(K,L)*FAD(I,K,L)) -
		@SUM(LINKS2H(K,L): G(K,L)*Z(K,L)) -
 		@SUM(LINKS1(K): F(K)*H(K));
   
!OGRANICENJA;
	@FOR( LINKS2(I,JJ):
			 @SUM(LINKS2H(K,L): Y(I,JJ,K,L))<=1);
	
	@FOR( LINKS3(I,JJ,K):
				@SUM(NODES(L): Y(I,JJ,K,L)) + @SUM(NODES(L)| K #NE# L: Y(I,JJ,K,L))<= H(K)) ;
	@FOR( LINKS2(I,K):
			@SUM(NODES(LL)| K #NE# LL: FAD(I,K,LL)-FAD(I,LL,K))-@SUM(LINKS2(JJ, L): W(I,JJ)*Y(I,JJ,K,L)- W(I,JJ)*Y(I,JJ,L,K)) = 0 );
	
	@FOR( LINKS3(I,K,LL)|K #NE# LL:
				 FAD(I,K,LL)<= @SUM(NODES(JJ): W(I,JJ))*Z(K,LL));

	@FOR(LINKS2H(K,LL)| K #NE# LL: Z(K,LL)<= H(K));

	@FOR(LINKS2H(K,LL)| K #NE# LL: Z(K,LL)<= H(LL));
				
	@FOR(LINKS3(I,K,LL): FAD(I,K,LL) >= 0);
	
	@FOR(NODES(K): @BIN(H(K)));

	@FOR(LINKS4(I,JJ,K,LL): @BIN(Y(I,JJ,K,LL))); 

	@FOR(LINKS2H(K, LL)| K #NE# LL: @BIN(Z(K,LL)));
	
END